STEP 8　タイトルとゲームオーバー

作つくってみよう

1. メッセージを2つ作つくる: イベントカテゴリの「メッセージ1を送おくる」の▼ →「新あたらしいメッセージ」→ スタート と ゲームオーバー
2. ステージのコードを作つくり替かえる（STEP7のコードに、背景はいけい・待まつ・送おくるを追加ついかする形かたちだよ）
   ステージ のコード①

   ⚑ が押されたとき
   背景を (タイトル v) にする
   [スコア v] を [0] にする
   [ライフ v] を [3] にする
   [レベル v] を [1] にする
   [てきスピード v] を [-3] にする
   <(スペース v) キーが押された> まで待つ
   [スタート v] を送る
   背景を (うちゅう v) にする
   ずっと
   もし <(スコア) > ((レベル) * (50))> なら
   [レベル v] を (1) ずつ変える
   [てきスピード v] を (-1) ずつ変える
   end
   end

   ⭐ 大事だいじなポイント
   「スペースキーが押おされるまで待まつ」がタイトル画面がめんの秘密ひみつ。
   ゲームはここで一時停止いちじていしして、スペースが押おされたら「スタート！」の合図あいずをみんなに送おくるんだ。
3. ステージにあと2つコードを追加ついか
   ステージ のコード②（ゲームオーバー見張みはり係かかり）

   [スタート v] を受け取ったとき
   <(ライフ) < (1)> まで待つ
   [ゲームオーバー v] を送る

   ステージ のコード③

   [ゲームオーバー v] を受け取ったとき
   背景を (ゲームオーバー v) にする
   [すべてを止める v]

4. じき・ビーム・てき の3つとも、、のコードを付つけ替かえる:
   「「が押おされたとき」の下したは「隠かくす」だけにして、動うごきのコードは「スタートを受うけ取とったとき」につなぎ替かえる
   じき の例れい

   ⚑ が押されたとき
   隠す

   [スタート v] を受け取ったとき
   表示する
   x座標を (0) 、y座標を (-140) にする
   ずっと
   もし <(右向き矢印 v) キーが押された> なら
   x座標を (10) ずつ変える
   end
   もし <(左向き矢印 v) キーが押された> なら
   x座標を (-10) ずつ変える
   end
   end

   ビームとてきも同おなじように、「ずっと〜」の上うえのハットブロックを「スタートを受うけ取とったとき」に変かえよう。（てき・ビームの本体ほんたいには「表示ひょうじする」は付つけないでね。クローンが表示ひょうじの係かかりだから！）

5. を押おして、タイトル→スペースでスタート→ライフ0でゲームオーバー、の流ながれを試ためそう！

✅ できたかチェック

• を押おすと タイトル画面がめんになって、てきもビームも出でない
• スペースキーで ゲームが始はじまる
• ライフが0になると ゲームオーバー画面がめんになって、すべて止とまる
• もう一度いちど一度いちどを押おすと またタイトルから遊あそべる

🚀 ミッション

• タイトル画面がめん・ゲームオーバー画面がめんの背景はいけいを、背景はいけいペイントで自分好じぶんごのみに描かき替かえよう
• チャレンジ: スタートのとき「3、2、1、GO!」のカウントダウンを出だせるかな？

🔧 うまくいかないとき

💾 ここまでのチェックポイント